Installez ce script a l'entrée de votre palace dans une porte et vous pourrez offrir un prop / avatar ou un adresse url ou un adresse e-mail a un de vos amis .

ON SIGNON

{

offeredAvatar GLOBAL

"" offeredAvatar =

offeredURL GLOBAL

"" offeredURL =

;

offerInScript GLOBAL

{ offeredAvatar GLOBAL

offeredURL GLOBAL

{ "$1" GREPSUB offeredURL =

" Vous offre un URL: $1 by " GREPSUB

WHOCHAT WHONAME & ". Pour accepter dite \"accepturl\"." & LOCALMSG

} CHATSTR "^;urloffer ([0-9a-zA-Z\./?=%:@~]+)" GREPSTR

WHOCHAT WHOME == NOT AND IF

;

{ "$1" GREPSUB prps =

{ "[ " prps & " ] SETPROPS" & offeredAvatar =

"@" WHOCHAT WHOPOS ITOA SWAP ITOA "," & SWAP & &

" Vous offre un prop " & WHOCHAT WHONAME &

". Pour accepter dite, \"accept\"." & LOCALMSG

} prps ".* .* .* .* .* .* .* .* .* .*" GREPSTR NOT

prps "-$" GREPSTR NOT AND

prps "- " GREPSTR NOT AND

prps ">$" GREPSTR NOT AND

prps "> " GREPSTR NOT AND

prps "<$" GREPSTR NOT AND

prps "< " GREPSTR NOT AND IF

"" CHATSTR =

} CHATSTR "^;avoffer [\[] ([0-9<>A-Fa-f -]+) [\]]" GREPSTR

WHOCHAT WHOME == NOT AND IF

} offerInScript DEF

offerOutScript GLOBAL

{ offeredAvatar GLOBAL

offeredURL GLOBAL

{

{ ";urloffer http://$1" GREPSUB WHOTARGET PRIVATEMSG }

{ " Vous devez l'offrir en privé." STATUSMSG } WHOTARGET IFELSE

"" CHATSTR =

} CHATSTR LOWERCASE "^offerweb ([0-9a-zA-Z\./?=%:@~]+)$" GREPSTR IF

{

{ ";urloffer palace://$1" GREPSUB WHOTARGET PRIVATEMSG }

{ " Vous devez l'offrir en privé." STATUSMSG } WHOTARGET IFELSE

""CHATSTR =

} CHATSTR LOWERCASE "^offerpal ([0-9a-zA-Z\./?=%:@~]+)$" GREPSTR IF

{

{ ";urloffer mailto:$1" GREPSUB WHOTARGET PRIVATEMSG }

{ " Vous devez l'offrir en privé." STATUSMSG } WHOTARGET IFELSE

""CHATSTR =

} CHATSTR LOWERCASE "^offermail ([0-9a-zA-Z\./?=%:@~]+)$" GREPSTR IF

{ offeredURL NETGOTO

"" CHATSTR =

} CHATSTR "accepturl" ==

offeredURL "" == NOT AND IF

{

{

{ 0 i = ";avoffer [ "

{ i USERPROP ITOA & " " & i ++ } { i NBRUSERPROPS < } WHILE "]" & WHOTARGET PRIVATEMSG

} NBRUSERPROPS IF

} { "Vous devez l'offrir en privé." STATUSMSG } WHOTARGET IFELSE

"" CHATSTR =

} CHATSTR "offer" == IF

;

{ offeredAvatar STRTOATOM EXEC

"" CHATSTR =

} "accept" CHATSTR ==

offeredAvatar "" == NOT AND IF

; Ne laissez pas quiconque dire les commandes automatisées

{ "" CHATSTR = } CHATSTR "^;avoffer" GREPSTR IF

{ "" CHATSTR = } CHATSTR "^;urloffer" GREPSTR IF

} offerOutScript DEF

}

----------------------------------------------------------------------------------------------------------

; porte 2 a installer dans toute les salles ( room ) et vous pourrez offrir partout sur palace

ON INCHAT { offerInScript GLOBAL offerInScript EXEC }

ON OUTCHAT { offerOutScript GLOBAL offerOutScript EXEC }