Conception d'une Prop Room
Bâtir une Prop Room n'est pas chose facile mais si vous suivez bien les procédures...vous y arriverez !
1. Pour vous faciliter le travail...il vous faudra modifier votre fichier "Cyborg.ipt" dans la section ON OUTCHAT qui se trouve dans le répertoire "Communities.com\ThePalace" (version 3.5 Win 95/98/ME/NT/XP). Je vous conseille de faire une sauvegarde (backup) du fichier "Cyborg.ipt" existant avant toute chose. Voici une adresse où vous pourrez vous faire construire un nouveau "Cyborg.ipt" sans être obligé de connaître le language "Iptscrae". Ce site s'appelle
...cliquez sur "BotBot" et "Let me try it"... cochez les scripts que vous aimez...et n'oubliez surtout pas "propspot"...cliquez sur "Build Cyborg.ipt".
...ou bien rajoutez ce script dans votre Cyborg.ipt dans la section ON OUTCHAT:
;Script propspot
{
"ON SELECT \x7b" LOGMSG
NBRUSERPROPS n =
{
0 i =
" \x5b"
{
" " i USERPROP ITOA & &
i ++
} { i n < } WHILE
" \x5d SETPROPS" & LOGMSG
} n IF
"\x7d" LOGMSG
"" CHATSTR =
} CHATSTR "propspot" == IF
2. Maintenant que vous avez votre nouveau "Cyborg.ipt" avec le script "propspot"...créez une pièce (Room) pour votre "Prop room"...et une porte (Door) ensuite dans "Door Info...Edit Script" mettez-y ce script:
ON SELECT {
{0 6 SETSPOTSTATELOCAL}
{6 GETSPOTSTATE 1 + 6 SETSPOTSTATELOCAL}
6 GETSPOTSTATE 9 > IFELSE
30 6 SETALARM
}
...cette porte servira de bouton pour changer de prop. Mettez comme option..."Normal" dans le cadre "Type"...cochez "Dont move here" et dans "Name"... écrivez "Suivant"...mettez une coche à "Show Name"...cliquez "Ok...Operator...Authoring Mode" . Placez cette porte pour qu'elle soit facile d'utilisation car c'est à cet endroit que vous cliquerez pour changer de prop. Tous les chiffres "6" qui se trouvent dans le script sont facultatifs...vous devrez les changer...vous verrez ce que je veux dire plus tard...
3. Créez une deuxième porte et dans "Door Info...Edit Script" mettez-y ce script:
ON ALARM {
CLEARPROPS
[
[ ]
[ ]
[ ]
[ ]
[ ]
[ ]
[ ]
[ ]
[ ]
[ ]
[ ]
] ME GETSPOTSTATE GET SETPROPS
"Prop #" ME GETSPOTSTATE ITOA + " of 10" + LOGMSG}
...placez-la dans un endroit à l'écart...c'est à l'intérieur de "[ ]" que vous écrirez chacun des numéros de série des 11 props que contiendra votre prop room...Prenez note du "ID" de cette porte (Door) car vous devrez changer tous les chiffres "6" qui se trouvent dans le premier script de la porte qui sert de bouton pour changer de prop par le "ID" de cette deuxième porte...dans le cadre "Type"...changez pour "Normal"...cliquez "Ok". Recliquez sur "Operator...Authoring Mode".
4. Toujours en mode God ou Wiz... mettez un prop...ouvrez votre log en cliquant sur "Options...Log Window". Dans la boîte de dialogue...écrivez "propspot" (ne mettez pas les guillemets) et vous apercevrez des numéros de série comme:[ -1345843763 -1345843085-1345842909 -1345843050 ]...ceci est le code pour identifier votre prop. Procédez de la même façon pour chaque prop que vous allez mettre à l'intérieur de votre prop room. Tous les numéros de série s'enregistreront dans votre "Log Window"...Inscrivez chacun des codes entre les "[ ]"...ex:
ON ALARM {
CLEARPROPS
[
[ -1345843763 -1345843085 -1345842909 -1345843050 ]
[ ]
...copier-coller s'avère très utile pour effectuer le travail. Après avoir terminé d'y insérer tous les codes de vos 11 props...n'oubliez pas de prendre en note le "ID" de cette porte avant de ...cliquez "Ok...Operator...Authoring Mode". Réouvrez la porte qui possède comme script:
ON SELECT {
{0 6 SETSPOTSTATELOCAL}
{6 GETSPOTSTATE 1 + 6 SETSPOTSTATELOCAL}
6 GETSPOTSTATE 9 > IFELSE
30 6 SETALARM
}
...cliquez sur "Edit Script"...changez tous les "6" (6 est le "ID" de la porte que je vous cite comme exemple) pour le "ID" de la porte qui vous a servi à inscrire les numéros de série à l'intérieur des "[ ]". Disons que le "ID" est 2 alors votre script devrait ce lire ainsi...
ON SELECT {
{0 2 SETSPOTSTATELOCAL}
{2 GETSPOTSTATE 1 + 2 SETSPOTSTATELOCAL}
2 GETSPOTSTATE 9 > IFELSE
30 2 SETALARM
}
...cliquez "OK...Operator...Authoring Mode"
Maintenant...cliquez sur "Suivant" pour revêtir chacun de vos props.
5. Pour créer un bouton "Retour"...Créez une nouvelle porte (Door) ensuite dans "Door Info...Edit Script"...mettez-y ce script:
ON SELECT{
{10 6 SETSPOTSTATELOCAL}
{6 GETSPOTSTATE 1 - 6 SETSPOTSTATELOCAL}
6 GETSPOTSTATE 1 < IFELSE
30 6 SETALARM
}
...cette porte servira de bouton pour faire marche arrière. Mettez comme option..."Normal" dans le cadre "Type"...cochez "Dont move here" et dans "Name"... écrivez "Retour"...mettez une coche à "Show Name"...cliquez "Ok". Recliquez sur "Operator...Authoring Mode" . Noubliez pas de changer tous les chiffres "6" comme dans l'exemple plus haut pour le chiffre 2.
6. Pour créer un bouton "Remise à zéro"...créez une nouvelle porte (Door) ensuite dans "Door Info...Edit Script"... mettez-y ce script:
ON SELECT { CLEARPROPS }
... Mettez comme option..."Normal" dans le cadre "Type"...cochez "Dont move here" et dans "Name"... écrivez "Remise à zéro"...mettez une coche à "Show Name"...cliquez "Ok". Recliquez sur "Operator...Authoring Mode"
Il est possible d'augmenter le nombre de prop en changeant le numéro "9" pour "10" dans le script: ...6 GETSPOTSTATE 9 > IFELSE ... "10" pour "11" dans le script: ..."Prop #" ME GETSPOTSTATE ITOA + " of 10" + LOGMSG} et "10" pour "11" dans le script {10 6 SETSPOTSTATELOCAL}. Rajoutez une "[ ]" de plus toujours à partir du haut du script et rajoutez-y un autre numéro de code. Si vous voulez en rajouter un de plus et bien changez le "10" pour "11" et "11" pour "12" et rajouter une autre "[ ]" toujours en commencant par le haut du script et ainsi de suite.
Pour conserver votre "Prop Room" propre...créez une nouvelle porte (Door) ensuite dans "Door Info...Edit Script"...mettez-y ce script:
ON LEAVE {
{ CLEARLOOSEPROPS } NBRROOMUSERS 2 < IF
}
...ceci effacera les props qui ont été laissés par mégarde dans la pièce.