Pour ce jeu télécharger ici les images :
images et sonNote: Ce jeu est à installer dans le PS.pat
ROOM
ID 7350
PRIVATE
NOPAINTING
NAME "Yahtzee m\E9lo"
PICT "image4.gif"
ARTIST "canonboy"
PICTURE ID 1 NAME "onept.gif" TRANSCOLOR 0 ENDPICTURE
PICTURE ID 2 NAME "dicered1.gif" TRANSCOLOR 0 ENDPICTURE
PICTURE ID 3 NAME "dicepurple2.gif" TRANSCOLOR 0 ENDPICTURE
PICTURE ID 4 NAME "dicered3.gif" TRANSCOLOR 0 ENDPICTURE
PICTURE ID 5 NAME "dicepurple4.gif" TRANSCOLOR 0 ENDPICTURE
PICTURE ID 6 NAME "dicered05.gif" TRANSCOLOR 0 ENDPICTURE
PICTURE ID 7 NAME "dicered06.gif" TRANSCOLOR 0 ENDPICTURE
PICTURE ID 8 NAME "yahtholdt.gif" ENDPICTURE
PICTURE ID 9 NAME "1mark.gif" TRANSCOLOR 0 ENDPICTURE
PICTURE ID 10 NAME "2mark.gif" TRANSCOLOR 0 ENDPICTURE
PICTURE ID 11 NAME "3mark.gif" TRANSCOLOR 0 ENDPICTURE
PICTURE ID 12 NAME "3xmark.gif" TRANSCOLOR 0 ENDPICTURE
PICTURE ID 13 NAME "3light.gif" TRANSCOLOR 0 ENDPICTURE
PICTURE ID 14 NAME "dicer1.gif" TRANSCOLOR 0 ENDPICTURE
PICTURE ID 15 NAME "dicer02.gif" TRANSCOLOR 0 ENDPICTURE
PICTURE ID 16 NAME "dicep3.gif" TRANSCOLOR 0 ENDPICTURE
PICTURE ID 17 NAME "unl.gif" ENDPICTURE
PICTURE ID 18 NAME "lck.gif" ENDPICTURE
PICTURE ID 19 NAME "yahtscr.gif" TRANSCOLOR 0 ENDPICTURE
PICTURE ID 20 NAME "silvertest.gif" TRANSCOLOR 0 ENDPICTURE
PICTURE ID 21 NAME "bluetest.gif" TRANSCOLOR 0 ENDPICTURE
PICTURE ID 22 NAME "aquatest.gif" TRANSCOLOR 0 ENDPICTURE
PICTURE ID 23 NAME "tealtest.gif" TRANSCOLOR 0 ENDPICTURE
PICTURE ID 24 NAME "greentest.gif" TRANSCOLOR 0 ENDPICTURE
PICTURE ID 25 NAME "purpletest.gif" TRANSCOLOR 0 ENDPICTURE
PICTURE ID 26 NAME "redtest.gif" TRANSCOLOR 0 ENDPICTURE
PICTURE ID 27 NAME "pinktest.gif" TRANSCOLOR 0 ENDPICTURE
PICTURE ID 28 NAME "orangetest.gif" TRANSCOLOR 0 ENDPICTURE
PICTURE ID 29 NAME "goldtest.gif" TRANSCOLOR 0 ENDPICTURE
PICTURE ID 35 NAME "image1.gif" ENDPICTURE
PICTURE ID 36 NAME "image2.gif" ENDPICTURE
PICTURE ID 37 NAME "image3.gif" ENDPICTURE
SPOT
ID 53
NAME "Background"
DONTMOVEHERE
OUTLINE 411,113 469,113 469,129 411,129
LOC 440,121
PICTS 0,0,0 35,-184,71 36,-184,71 37,-184,71 ENDPICTS
SCRIPT
ON SELECT { mx GLOBAL
MousePos Swap mx =
{ { 0 ME SETSPOTSTATELOCAL }
{ ME GETSPOTSTATE 1 + ME SETSPOTSTATELOCAL }
ME GETSPOTSTATE 2 > IFELSE } mx 440 > IF
{ { 3 ME SETSPOTSTATELOCAL }
{ ME GETSPOTSTATE 1 - ME SETSPOTSTATELOCAL }
ME GETSPOTSTATE 1 < IFELSE } mx 440 < IF
["Image 1" " Image 2" " Image 3" " Image 4"] ME GetSpotState Get ", " &
["off" "Gray" "Blue" "Aqua" "Teal" "Green" "Purple" "Red" "Pink" "Orange" "Gold"] 28 GetSpotState Get &
StatusMsg
}
ENDSCRIPT
ENDSPOT
SPOT
ID 28
NAME "Yahtzee.gif"
DONTMOVEHERE
OUTLINE 206,5 268,5 268,28 206,28
LOC 234,16
PICTS 19,24,53 20,24,53 21,24,53 22,24,53 23,24,53 24,24,53 25,24,53 26,24,53 27,24,53 28,24,53 29,24,53 ENDPICTS
SCRIPT
ON ENTER {
{ 3 26 SetSpotState} 24 GetSpotState NOT IF
}
;
ON SELECT { mx GLOBAL
MousePos Swap mx =
{ { 0 ME SETSPOTSTATELOCAL }
{ ME GETSPOTSTATE 1 + ME SETSPOTSTATELOCAL }
ME GETSPOTSTATE 9 > IFELSE } mx 236 > IF
{ { 10 ME SETSPOTSTATELOCAL }
{ ME GETSPOTSTATE 1 - ME SETSPOTSTATELOCAL }
ME GETSPOTSTATE 1 < IFELSE } mx 236 < IF
["Fond 1" "Fond 2" "Fond 3" "Fond 4"] 53 GetSpotState Get ", " &
["off" "Gray" "Blue" "Aqua" "Teal" "Green" "Purple" "Red" "Pink" "Orange" "Gold"] ME GetSpotState Get &
StatusMsg
}
;
ON LEAVE { { PaintClear ClearLooseProps
0 i = { 0 i SetSpotState i ++ } { i 44 < } While
} NbrRoomUsers 2 < IF }
ENDSCRIPT
ENDSPOT
SPOT
ID 1
OUTLINE 150,44 176,44 176,70 150,70
LOC 163,57
PICTS 1,0,0 2,0,0 3,0,0 4,0,0 5,0,0 6,0,0 7,0,0 14,0,0 15,0,0 16,0,0 ENDPICTS
ENDSPOT
SPOT
ID 2
OUTLINE 186,44 212,44 212,70 186,70
LOC 199,57
PICTS 1,0,0 2,0,0 3,0,0 4,0,0 5,0,0 6,0,0 7,0,0 14,0,0 15,0,0 16,0,0 ENDPICTS
ENDSPOT
SPOT
ID 3
OUTLINE 224,44 250,44 250,70 224,70
LOC 237,57
PICTS 1,0,0 2,0,0 3,0,0 4,0,0 5,0,0 6,0,0 7,0,0 14,0,0 15,0,0 16,0,0 ENDPICTS
ENDSPOT
SPOT
ID 4
OUTLINE 262,44 288,44 288,70 262,70
LOC 275,57
PICTS 1,0,0 2,0,0 3,0,0 4,0,0 5,0,0 6,0,0 7,0,0 14,0,0 15,0,0 16,0,0 ENDPICTS
ENDSPOT
SPOT
ID 5
OUTLINE 300,44 326,44 326,70 300,70
LOC 313,57
PICTS 1,0,0 2,0,0 3,0,0 4,0,0 5,0,0 6,0,0 7,0,0 14,0,0 15,0,0 16,0,0 ENDPICTS
ENDSPOT
SPOT
ID 11
DONTMOVEHERE
OUTLINE 102,9 132,9 132,19 102,19
LOC 132,14
PICTS 1,0,0 9,0,0 ENDPICTS
SCRIPT
ON SELECT { dd GLOBAL crv GLOBAL co GLOBAL ut GLOBAL myturn GLOBAL
{ dd STRTOATOM EXEC 0 GET crv = ME co = ut crv + subtotal =
63 subtotal - need =
"@0,120 Ones add " crv ITOA & " for subtotal = " & subtotal itoa & ". Still need " & need itoa & " pour les 63 a du obtenir la bonification de 35 points." & LOCALMSG
} myturn ME GETSPOTSTATE NOT AND IF
}
ENDSCRIPT
ENDSPOT
SPOT
ID 12
DONTMOVEHERE
OUTLINE 102,24 132,24 132,36 102,36
LOC 132,30
PICTS 1,0,0 9,0,0 ENDPICTS
SCRIPT
ON SELECT { dd GLOBAL crv GLOBAL co GLOBAL ut GLOBAL myturn GLOBAL
{ dd STRTOATOM EXEC 1 GET 2 * crv = ME co = ut crv + subtotal =
63 subtotal - need =
"@0,120 Twos add " crv ITOA & " for subtotal = " & subtotal itoa & ". Still need " & need itoa & " pour les 63 a du obtenir la bonification de 35 points." & LOCALMSG
} myturn ME GETSPOTSTATE NOT AND IF
}
ENDSCRIPT
ENDSPOT
SPOT
ID 13
DONTMOVEHERE
OUTLINE 102,38 132,38 132,50 102,50
LOC 132,44
PICTS 1,0,0 9,0,0 ENDPICTS
SCRIPT
ON SELECT { dd GLOBAL crv GLOBAL co GLOBAL ut GLOBAL myturn GLOBAL
{ dd STRTOATOM EXEC 2 GET 3 * crv = ME co = ut crv + subtotal =
63 subtotal - need =
"@0,120 Threes add " crv ITOA & " for subtotal = " & subtotal itoa & ". Still need " & need itoa & " pour les 63 a du obtenir la bonification de 35 points." & LOCALMSG
} myturn ME GETSPOTSTATE NOT AND IF
}
ENDSCRIPT
ENDSPOT
SPOT
ID 14
DONTMOVEHERE
OUTLINE 102,52 132,52 132,64 102,64
LOC 132,58
PICTS 1,0,0 9,0,0 ENDPICTS
SCRIPT
ON SELECT { dd GLOBAL crv GLOBAL co GLOBAL ut GLOBAL myturn GLOBAL
{ dd STRTOATOM EXEC 3 GET 4 * crv = ME co = ut crv + subtotal =
63 subtotal - need =
"@0,120 Fours add " crv ITOA & " for subtotal = " & subtotal itoa & ". Still need " & need itoa & " pour les 63 a du obtenir la bonification de 35 points." & LOCALMSG
} myturn ME GETSPOTSTATE NOT AND IF
}
ENDSCRIPT
ENDSPOT
SPOT
ID 15
DONTMOVEHERE
OUTLINE 102,65 132,65 132,77 102,77
LOC 132,71
PICTS 1,0,0 9,0,0 ENDPICTS
SCRIPT
ON SELECT { dd GLOBAL crv GLOBAL co GLOBAL ut GLOBAL myturn GLOBAL
{ dd STRTOATOM EXEC 4 GET 5 * crv = ME co = ut crv + subtotal =
63 subtotal - need =
"@0,120 Fives add " crv ITOA & " for subtotal = " & subtotal itoa & ". Still need " & need itoa & " pour les 63 a du obtenir la bonification de 35 points." & LOCALMSG
} myturn ME GETSPOTSTATE NOT AND IF
}
ENDSCRIPT
ENDSPOT
SPOT
ID 16
DONTMOVEHERE
OUTLINE 102,79 132,79 132,91 102,91
LOC 132,84
PICTS 1,0,0 9,0,0 ENDPICTS
SCRIPT
ON SELECT { dd GLOBAL crv GLOBAL co GLOBAL ut GLOBAL myturn GLOBAL
{ dd STRTOATOM EXEC 5 GET 6 * crv = ME co = ut crv + subtotal =
63 subtotal - need =
"@0,120 Sixes add " crv ITOA & " for subtotal = " & subtotal itoa & ". Still need " & need itoa & " pour les 63 a du obtenir la bonification de 35 points." & LOCALMSG
} myturn ME GETSPOTSTATE NOT AND IF
}
ENDSCRIPT
ENDSPOT
SPOT
ID 17
DONTMOVEHERE
OUTLINE 348,6 386,6 386,18 348,18
LOC 386,12
PICTS 1,0,0 9,0,0 ENDPICTS
SCRIPT
ON SELECT { dd GLOBAL crv GLOBAL co GLOBAL dt GLOBAL
myturn GLOBAL
{ dd STRTOATOM EXEC ddav = 0 crv =
{ tdv = { dt crv = } tdv 2 > IF
} ddav FOREACH
ME co =
"@365,11 Cela vous donnera un pointage de " crv ITOA & LOCALMSG
} myturn ME GETSPOTSTATE NOT AND IF
}
ENDSCRIPT
ENDSPOT
SPOT
ID 18
DONTMOVEHERE
OUTLINE 348,20 386,20 386,34 348,34
LOC 386,26
PICTS 1,0,0 9,0,0 ENDPICTS
SCRIPT
ON SELECT { dd GLOBAL crv GLOBAL co GLOBAL dt GLOBAL
myturn GLOBAL
{ dd STRTOATOM EXEC ddav = 0 crv =
{ tdv = { dt crv = } tdv 3 > IF
} ddav FOREACH
ME co =
"@365,24 Cela vous donnera un pointage de " crv ITOA & LOCALMSG
} myturn ME GETSPOTSTATE NOT AND IF
}
ENDSCRIPT
ENDSPOT
SPOT
ID 19
DONTMOVEHERE
OUTLINE 348,36 386,36 386,48 348,48
LOC 386,42
PICTS 1,0,0 9,0,0 ENDPICTS
SCRIPT
ON SELECT { dd GLOBAL crv GLOBAL co GLOBAL dt GLOBAL
myturn GLOBAL
{ dd "[145]" GREPSTR NOT 25 * crv =
ME co =
"@365,37 Cela vous donnera un pointage de " crv ITOA & LOCALMSG
} myturn ME GETSPOTSTATE NOT AND IF
}
ENDSCRIPT
ENDSPOT
SPOT
ID 20
DONTMOVEHERE
OUTLINE 348,50 386,50 386,62 348,62
LOC 386,56
PICTS 1,0,0 9,0,0 ENDPICTS
SCRIPT
ON SELECT { dd GLOBAL crv GLOBAL co GLOBAL dt GLOBAL
myturn GLOBAL
{ dd " [12] [12] [12] [12] " GREPSTR 30 * crv =
ME co =
"@365,51 Cela vous donnera un pointage de " crv ITOA & LOCALMSG
} myturn ME GETSPOTSTATE NOT AND IF
}
ENDSCRIPT
ENDSPOT
SPOT
ID 21
DONTMOVEHERE
OUTLINE 348,64 386,64 386,76 348,76
LOC 386,70
PICTS 1,0,0 9,0,0 ENDPICTS
SCRIPT
ON SELECT { dd GLOBAL crv GLOBAL co GLOBAL dt GLOBAL
myturn GLOBAL
{ dd " 1 1 1 1 1 " GREPSTR 40 * crv =
ME co =
"@365,66 Cela vous donnera un pointage de " crv ITOA & LOCALMSG
} myturn ME GETSPOTSTATE NOT AND IF
}
ENDSCRIPT
ENDSPOT
SPOT
ID 22
DONTMOVEHERE
OUTLINE 348,94 386,94 386,106 348,106
LOC 386,98
PICTS 1,0,0 9,0,0 ENDPICTS
SCRIPT
ON SELECT { dd GLOBAL crv GLOBAL co GLOBAL dt GLOBAL
myturn GLOBAL
{ dt crv = ME co =
"@365,92 Cela vous donnera un pointage de " crv ITOA & LOCALMSG
} myturn ME GETSPOTSTATE NOT AND IF
}
ENDSCRIPT
ENDSPOT
SPOT
ID 23
DONTMOVEHERE
OUTLINE 348,79 386,79 386,91 348,91
LOC 372,84
PICTS 1,0,0 9,0,0 10,0,0 11,0,0 12,0,0 12,0,0 12,0,0 12,0,0 12,0,0 12,0,0 12,0,0 12,0,0 12,0,0 ENDPICTS
SCRIPT
ON SELECT { yhtz GLOBAL co GLOBAL dd GLOBAL myturn GLOBAL
crv GLOBAL mysc GLOBAL btt GLOBAL
{ dd "5" SUBSTR yts =
{
{ "@220,110 Désolé, vous avez mis hors de votre ligne de yahtzee plus tôt - vous êtes inéligible pour une bonification." LOCALMSG
} yts yhtz 0 < AND IF
{ ")applause " USERNAME " Colecte une bonification de Yahtzee!" & & ROOMMSG
"@220,110 Le joker règne -- vous obtenez de le marquer sur une ligne régulière aussi bien!" LOCALMSG
100 mysc += ME GETSPOTSTATE 1 + ME SETSPOTSTATE
1 btt = yhtz ++
} yts yhtz 0 > AND btt NOT AND IF
}
{ ;yahtzee pour la premiere fois, -1 if yts is 0, 1 if yts is 1
yts 50 * crv = ME co =
"@365,101 Ceci vous donneras un pointage de " crv ITOA & LOCALMSG
{ "@220,110 !ATTENTION: la mise à zéro hors de cette boîte vous rend inéligible pour des bonifications de yahtzee!" LOCALMSG
} crv NOT IF
} yhtz IFELSE
} myturn IF
}
ENDSCRIPT
ENDSPOT
SPOT
ID 10
DONTMOVEHERE
OUTLINE 298,42 328,42 328,72 298,72
LOC 314,57
PICTS 1,0,0 8,0,0 ENDPICTS
SCRIPT
ON SELECT { myturn GLOBAL
{ ME GETSPOTSTATE NOT ME SETSPOTSTATE
} myturn 26 GETSPOTSTATE AND IF
}
ENDSCRIPT
ENDSPOT
SPOT
ID 9
DONTMOVEHERE
OUTLINE 260,42 290,42 290,72 260,72
LOC 276,57
PICTS 1,0,0 8,0,0 ENDPICTS
SCRIPT
ON SELECT { myturn GLOBAL
{ ME GETSPOTSTATE NOT ME SETSPOTSTATE
} myturn 26 GETSPOTSTATE AND IF
}
ENDSCRIPT
ENDSPOT
SPOT
ID 8
DONTMOVEHERE
OUTLINE 222,42 252,42 252,72 222,72
LOC 238,57
PICTS 1,0,0 8,0,0 ENDPICTS
SCRIPT
ON SELECT { myturn GLOBAL
{ ME GETSPOTSTATE NOT ME SETSPOTSTATE
} myturn 26 GETSPOTSTATE AND IF
}
ENDSCRIPT
ENDSPOT
SPOT
ID 7
DONTMOVEHERE
OUTLINE 184,42 214,42 214,72 184,72
LOC 200,57
PICTS 1,0,0 8,0,0 ENDPICTS
SCRIPT
ON SELECT { myturn GLOBAL
{ ME GETSPOTSTATE NOT ME SETSPOTSTATE
} myturn 26 GETSPOTSTATE AND IF
}
ENDSCRIPT
ENDSPOT
SPOT
ID 6
DONTMOVEHERE
OUTLINE 148,42 178,42 178,72 148,72
LOC 164,57
PICTS 1,0,0 8,0,0 ENDPICTS
SCRIPT
ON SELECT { myturn GLOBAL
{ ME GETSPOTSTATE NOT ME SETSPOTSTATE
} myturn 26 GETSPOTSTATE AND IF
}
ENDSCRIPT
ENDSPOT
SPOT
ID 24
NAME "Start Game"
DONTMOVEHERE
OUTLINE 143,5 190,5 190,28 143,28
LOC 166,16
SCRIPT
ON ENTER { { "Une partie de YAHTZEE est présentement en cours- clique départ pour la joindre!" LOCALMSG } ME GETSPOTSTATE WHONAME "." GREPSTR IF
{ 0 ME SETSPOTSTATE } ME GETSPOTSTATE WHOME == IF
{ POSX 160 RANDOM 224 + SETPOS } POSY 225 < IF
}
ON SELECT { ref GLOBAL plyrs GLOBAL ad GLOBAL hsc GLOBAL phsc GLOBAL
{ { "La partie est présentement commencé. Clique jouer pour prendre place." LOCALMSG }
{ "Mettre a zero la partie (reset), clique sur départ pour une nouvelle partie." LOCALMSG
0 ME SETSPOTSTATE ";5" SAY
{ cr ++ 0 cr SETSPOTSTATE } { cr 23 < } WHILE
} ME GETSPOTSTATE WHONAME "." GREPSTR IFELSE
}
{ WHOME ME SETSPOTSTATE 1 ref = "" plyrs = "-" ad = 0 hsc = "" phsc =
USERNAME " a commencé un jeu de Yahtzee! Pour joindre le jeu cliquez sur départ!" & Say
USERNAME ", Cliquez le bouton jouer pour commencer le jeu après que tous les joueurs se soit joind." & Say
} ME GETSPOTSTATE IFELSE
}
ON INCHAT { ref GLOBAL plyrs GLOBAL phsc GLOBAL hsc GLOBAL
{
{ DUP GLOBAL 0 SWAP =
} [ ref rollt crv mysc ut yhtz plyrs ckbxs myturn co phsc hsc btt ] FOREACH
"" plyrs =
} CHATSTR ";5" == IF
{ 0 ref = "" plyrs = "" phsc = 0 hsc =
} ref WHOME ME GETSPOTSTATE <> AND IF
}
ON OUTCHAT { { "" CHATSTR = } CHATSTR "^;" GREPSTR IF }
ON ALARM { plyrs GLOBAL hsc GLOBAL phsc GLOBAL ref GLOBAL
{ { "@200,50 !Partie terminé!" ROOMMSG
{ "@230,100 ..et nôtre gagnant(e) est: " ROOMMSG
"@250,150 )applause !" phsc & "!!" & ROOMMSG
} hsc IF
0 ref = 1 sp =
{ 0 sp SETSPOTSTATE sp ++ } { sp 25 < } WHILE
{ ";5" SAY } 60 ALARMEXEC
} plyrs "." GREPSTR NOT IF
} ref IF
}
ENDSCRIPT
ENDSPOT
SPOT
ID 25
NAME "PLAY"
DONTMOVEHERE
OUTLINE 286,83 333,83 333,107 286,107
LOC 309,95
SCRIPT
ON ENTER { ad GLOBAL "" ad =
"Pour distribution gratuite seulement!" LOGMSG
}
ON OUTCHAT { ref GLOBAL plyrs GLOBAL
{ "" CHATSTR =
plyrs "^(.*)-[0-9+]-$" GREPSTR POP
"$1" GREPSUB plyrs = 1 25 SETALARM
} ref CHATSTR "enleve le joueur" == AND IF
}
ON SELECT { myturn GLOBAL btt GLOBAL
{ co GLOBAL crv GLOBAL mysc GLOBAL ut GLOBAL ckbxs GLOBAL
dd GLOBAL yhtz GLOBAL
{ crv mysc += "J'ai un pointage de " mysc ITOA & SAY
0 btt =
{ crv ut += } co 17 < IF
{ 1 co SETSPOTSTATE } co 23 < IF
{ 1 co SETSPOTSTATE dd "5" SUBSTR 2 * 1 - yhtz =
} co 23 == yhtz NOT AND IF
10 cs = 0 ckbxs = 1 vl =
{ cs ++ cs GETSPOTSTATE ckd = { 1 ckd = } cs co == IF
{ vl ckbxs += } ckd IF 2 vl *=
} { cs 22 < } WHILE
0 myturn =
{ ";3" SAY }
{ { 35 mysc += "@400,150 !TABLE BONUS!" LOCALMSG
} ut 62 > IF
";4" WHOME ITOA & "-" & mysc ITOA & SAY
{ DUP GLOBAL 0 SWAP =
} [ rollt crv mysc ut yhtz ckbxs myturn co btt ] FOREACH
} ckbxs 4095 < yhtz NOT OR IFELSE
} co IF
}
{ ";1" SAY "dice2" SOUND } myturn IFELSE
}
ON INCHAT { ref GLOBAL plyrs GLOBAL ad GLOBAL
mysc GLOBAL ckbxs GLOBAL ut GLOBAL yhtz GLOBAL
plyrs GLOBAL hsc GLOBAL phsc GLOBAL
ad "." GREPSTR stt =
{ "-" WHOCHAT ITOA & "-" & ad =
{ "Tu est déja en jeu, " WHOCHAT WHONAME &
WHOCHAT PRIVATEMSG
}
{ WHOCHAT WHONAME " à joint le jeu!" & Say
";2" WHOCHAT ITOA & WHOCHAT PRIVATEMSG
plyrs ad & plyrs =
} plyrs ad SUBSTR IFELSE
{ "" ad = } stt NOT IF
} CHATSTR ";1" == ref AND IF
{ ;initialize variables to play
0 mysc = 0 ckbxs = 0 ut = 0 yhtz =
} CHATSTR ";2" WHOME ITOA & == IF
{ 90 ME SETALARM
} ";3" CHATSTR == ref AND IF
{ "-$1-" GREPSUB pq =
"$2" GREPSUB ATOI ps =
")applause !" "$1" GREPSUB ATOI WHONAME " a terminé avec des points finals de " & &
"$2!" GREPSUB & Say
{ "@150,0 !Meilleur pointage dans cette partie BRAVO !" Say
"$1" GREPSUB ATOI WHONAME phsc = ps hsc =
} ps hsc > IF
plyrs "^(.*)" pq & "(.*)$" & GREPSTR POP
"$1$2" GREPSUB plyrs =
60 24 SETALARM 120 ME SETALARM
} CHATSTR "^;4([0-9]+)-([0-9]+)$" GREPSTR ref AND IF
{ { "$1$2" GREPSUB plyrs =
WHOCHAT WHONAME " as quitté la partie !" & Say
{ 1 ME SETALARM } "$2" GREPSUB "" == IF
} plyrs "^(.*)-" WHOCHAT ITOA "-(.*)$" & & GREPSTR IF
} CHATSTR ";6" == ref AND IF
}
ON ALARM { plyrs GLOBAL
plyrs "^-([0-9]+)-(.*)$" GREPSTR POP
"$1" GREPSUB cp = "$2" GREPSUB oth =
{ oth GREPSUB plyrs = plyrs "^-([0-9]+)-(.*)$" GREPSTR POP
"$1" GREPSUB cp = "$2" GREPSUB oth =
} { cp ATOI WHONAME "." GREPSTR NOT plyrs "" == NOT AND } WHILE
{ "@" cp ATOI WHOPOS ITOA SWAP ITOA "," & SWAP & & " " & cp ATOI WHONAME " C'est à mon tour !!!" & & ROOMMSG
";3" cp & cp ATOI PRIVATEMSG
oth "-" & cp & "-" & plyrs =
}
{ 30 24 SETALARM
} plyrs "" == NOT IFELSE
}
ON LEAVE { ";6" SAY }
ENDSCRIPT
ENDSPOT
SPOT
ID 26
NAME "Roll"
DONTMOVEHERE
OUTLINE 146,82 190,82 190,108 146,108
LOC 170,95
PICTS 13,-114,25 13,-149,25 13,-184,25 1,0,0 ENDPICTS
SCRIPT
ON ENTER {
{ DUP GLOBAL 0 SWAP =
} [ ref rollt crv mysc ut yhtz plyrs ckbxs myturn co ] FOREACH
}
ON SELECT { ref GLOBAL ad GLOBAL rollt GLOBAL crv GLOBAL myturn GLOBAL
{ "" ad = 1 25 SETALARM }
{ { { ME GETSPOTSTATE 1 + ME SETSPOTSTATE
6 rollt = 0 crv =
1 ME SETALARM
}ME GETSPOTSTATE 3 < IF
} myturn IF
} ref ad ".." GREPSTR AND IFELSE
}
ON INCHAT {
mysc GLOBAL ckbxs GLOBAL ut GLOBAL yhtz GLOBAL
rollt GLOBAL myturn GLOBAL co GLOBAL
{ { 0 SWAP SETSPOTSTATE } [ 6 7 8 9 10 ] FOREACH
1 myturn = 11 sp = ckbxs tckbxs =
{ tckbxs DUP 2 / 2 * - sp SETSPOTSTATE
2 tckbxs /= sp ++
} { sp 23 < } WHILE
{ 1 23 SETSPOTSTATE
{ yhtz 23 SETSPOTSTATE } yhtz 1 > IF
}
{ 0 23 SETSPOTSTATE } yhtz IFELSE
0 ME SETSPOTSTATE 0 crv = 0 co =
{ 0 SWAP SETSPOTSTATE } [ 1 2 3 4 5 ] FOREACH
} ";3" WHOME ITOA & CHATSTR == IF
}
ON ALARM { rollt GLOBAL dd GLOBAL dt GLOBAL
crv GLOBAL 0 crv = co GLOBAL 0 co =
{ ")dice2" SAY } rollt 6 == IF
{ 0 cr = rollt --
{ cr ++
{ 7 rollt cr + DUP 3 / 3 * - + cr SETSPOTSTATE
} cr 5 + GETSPOTSTATE NOT IF
} { cr 5 < } WHILE
30 ME SETALARM
}
{ 1 27 SETALARM
} rollt IFELSE
}
ENDSCRIPT
ENDSPOT
SPOT
ID 27
NAME "Quit"
DONTMOVEHERE
OUTLINE 285,5 331,5 331,28 285,28
LOC 308,16
SCRIPT
ON SELECT { ref GLOBAL ";6" SAY
{ { DUP GLOBAL 0 SWAP =
} [ rollt crv mysc ut yhtz ckbxs myturn co btt ] FOREACH
}
{";5" WHOME PRIVATEMSG } ref IFELSE
}
ON ALARM { dt GLOBAL dd GLOBAL
0 dt = [ 0 0 0 0 0 0 ] dd =
{ dc = dc 5 + GETSPOTSTATE lck =
{ 6 RANDOM 1 + dv = dv dc SETSPOTSTATE }
{ dc GETSPOTSTATE dv = } lck NOT IFELSE
dv dt += dd dv 1 - GET 1 + dd dv 1 - PUT
} [ 1 2 3 4 5 ] FOREACH
"[ " { ITOA + " " + } dd FOREACH
" ]" & dd =
{ "@105,268 )applause !YAHTZEE!!" ROOMMSG
} dd "5" SUBSTR IF
}
ENDSCRIPT
ENDSPOT
DOOR
LOCKABLE
ID 44
NAME "Lock"
DONTMOVEHERE
OUTLINE 480,112 504,112 504,132 480,132
LOC 492,122
PICTS 17,0,0 18,-3,0 ENDPICTS
SCRIPT
ON SELECT
{
{ ME UNLOCK }
{ ME LOCK } ME ISLOCKED IFELSE
}
ENDSCRIPT
ENDSPOT
ENDROOM