ROOM
ID 269
PRIVATE
NAME "Yahtzee 6 Corral"
PICT "yahcorral.gif"
PICTURE ID 1 NAME "onept.gif" TRANSCOLOR 0 ENDPICTURE
PICTURE ID 2 NAME "dicecor1.gif" TRANSCOLOR 0 ENDPICTURE
PICTURE ID 3 NAME "dicecor2.gif" TRANSCOLOR 0 ENDPICTURE
PICTURE ID 4 NAME "dicecor3.gif" TRANSCOLOR 0 ENDPICTURE
PICTURE ID 5 NAME "dicecor4.gif" TRANSCOLOR 0 ENDPICTURE
PICTURE ID 6 NAME "dicecor5.gif" TRANSCOLOR 0 ENDPICTURE
PICTURE ID 7 NAME "dicecor6.gif" TRANSCOLOR 0 ENDPICTURE
PICTURE ID 8 NAME "yholdwood.gif" TRANSCOLOR 0 ENDPICTURE
PICTURE ID 9 NAME "1markgold.gif" TRANSCOLOR 0 ENDPICTURE
PICTURE ID 10 NAME "2markgold.gif" TRANSCOLOR 0 ENDPICTURE
PICTURE ID 11 NAME "3markgold.gif" TRANSCOLOR 0 ENDPICTURE
PICTURE ID 12 NAME "3xmarkgold.gif" TRANSCOLOR 0 ENDPICTURE
PICTURE ID 13 NAME "badgelights.gif" TRANSCOLOR 0 ENDPICTURE
PICTURE ID 14 NAME "dicecr1.gif" TRANSCOLOR 0 ENDPICTURE
PICTURE ID 15 NAME "dicecr2.gif" TRANSCOLOR 0 ENDPICTURE
PICTURE ID 16 NAME "dicecr3.gif" TRANSCOLOR 0 ENDPICTURE
SPOT
ID 1
OUTLINE 25,150 55,150 55,177 25,177
LOC 40,162
PICTS 1,0,0 2,0,0 3,0,0 4,0,0 5,0,0 6,0,0 7,0,0 14,0,0 15,0,0 16,0,0 ENDPICTS
ENDSPOT
SPOT
ID 2
OUTLINE 66,149 96,149 96,176 66,176
LOC 81,161
PICTS 1,0,0 2,0,0 3,0,0 4,0,0 5,0,0 6,0,0 7,0,0 14,0,0 15,0,0 16,0,0 ENDPICTS
ENDSPOT
SPOT
ID 3
OUTLINE 107,150 137,150 137,177 107,177
LOC 122,162
PICTS 1,0,0 2,0,0 3,0,0 4,0,0 5,0,0 6,0,0 7,0,0 14,0,0 15,0,0 16,0,0 ENDPICTS
ENDSPOT
SPOT
ID 4
OUTLINE 149,150 179,150 179,177 149,177
LOC 164,162
PICTS 1,0,0 2,0,0 3,0,0 4,0,0 5,0,0 6,0,0 7,0,0 14,0,0 15,0,0 16,0,0 ENDPICTS
ENDSPOT
SPOT
ID 5
OUTLINE 190,149 220,149 220,176 190,176
LOC 205,161
PICTS 1,0,0 2,0,0 3,0,0 4,0,0 5,0,0 6,0,0 7,0,0 14,0,0 15,0,0 16,0,0 ENDPICTS
ENDSPOT
SPOT
ID 6
OUTLINE 230,149 260,149 260,176 230,176
LOC 246,161
PICTS 1,0,0 2,0,0 3,0,0 4,0,0 5,0,0 6,0,0 7,0,0 14,0,0 15,0,0 16,0,0 ENDPICTS
ENDSPOT
SPOT
ID 13
DONTMOVEHERE
OUTLINE 116,24 170,24 170,40 116,40
LOC 156,33
PICTS 1,0,0 9,0,0 ENDPICTS
SCRIPT
ON SELECT { dd GLOBAL crv GLOBAL co GLOBAL
myturn GLOBAL
{ dd STRTOATOM EXEC 0 GET crv = ME co =
"@167, 34 Ceci Vous Donne Un Score De " crv ITOA & LOCALMSG
} myturn ME GETSPOTSTATE NOT AND IF
}
ENDSCRIPT
ENDSPOT
SPOT
ID 14
DONTMOVEHERE
OUTLINE 116,41 170,41 170,56 116,56
LOC 156,49
PICTS 1,0,0 9,0,0 ENDPICTS
SCRIPT
ON SELECT { dd GLOBAL crv GLOBAL co GLOBAL
myturn GLOBAL
{ dd STRTOATOM EXEC 1 GET 2 * crv = ME co =
"@167,51 Ceci Vous Donne Un Score De " crv ITOA & LOCALMSG
} myturn ME GETSPOTSTATE NOT AND IF
}
ENDSCRIPT
ENDSPOT
SPOT
ID 15
DONTMOVEHERE
OUTLINE 116,57 170,57 170,73 116,73
LOC 156,66
PICTS 1,0,0 9,0,0 ENDPICTS
SCRIPT
ON SELECT { dd GLOBAL crv GLOBAL co GLOBAL
myturn GLOBAL
{ dd STRTOATOM EXEC 2 GET 3 * crv = ME co =
"@167,66 Ceci Vous Donne Un Score De " crv ITOA & LOCALMSG
} myturn ME GETSPOTSTATE NOT AND IF
}
ENDSCRIPT
ENDSPOT
SPOT
ID 16
DONTMOVEHERE
OUTLINE 116,74 170,74 170,90 116,90
LOC 156,83
PICTS 1,0,0 9,0,0 ENDPICTS
SCRIPT
ON SELECT { dd GLOBAL crv GLOBAL co GLOBAL
myturn GLOBAL
{ dd STRTOATOM EXEC 3 GET 4 * crv = ME co =
"@167,84 Ceci Vous Donne Un Score De " crv ITOA & LOCALMSG
} myturn ME GETSPOTSTATE NOT AND IF
}
ENDSCRIPT
ENDSPOT
SPOT
ID 17
DONTMOVEHERE
OUTLINE 116,91 170,91 170,107 116,107
LOC 156,100
PICTS 1,0,0 9,0,0 ENDPICTS
SCRIPT
ON SELECT { dd GLOBAL crv GLOBAL co GLOBAL
myturn GLOBAL
{ dd STRTOATOM EXEC 4 GET 5 * crv = ME co =
"@167,100 Ceci Vous Donne Un Score De " crv ITOA & LOCALMSG
} myturn ME GETSPOTSTATE NOT AND IF
}
ENDSCRIPT
ENDSPOT
SPOT
ID 18
DONTMOVEHERE
OUTLINE 116,108 170,108 170,123 116,123
LOC 156,116
PICTS 1,0,0 9,0,0 ENDPICTS
SCRIPT
ON SELECT { dd GLOBAL crv GLOBAL co GLOBAL
myturn GLOBAL
{ dd STRTOATOM EXEC 5 GET 6 * crv = ME co =
"@167,117 Ceci Vous Donne Un Score De " crv ITOA & LOCALMSG
} myturn ME GETSPOTSTATE NOT AND IF
}
ENDSCRIPT
ENDSPOT
SPOT
ID 19
DONTMOVEHERE
OUTLINE 311,7 366,7 366,22 311,22
LOC 343,16
PICTS 1,0,0 9,0,0 ENDPICTS
SCRIPT
ON SELECT { dd GLOBAL crv GLOBAL co GLOBAL dt GLOBAL
myturn GLOBAL
{ dd "[3456]" GREPSTR dt * crv =
ME co =
"@343,18 Ceci Vous Donne Un Score De " crv ITOA & LOCALMSG
} myturn ME GETSPOTSTATE NOT AND IF
}
ENDSCRIPT
ENDSPOT
SPOT
ID 20
DONTMOVEHERE
OUTLINE 311,23 366,23 366,40 311,40
LOC 343,32
PICTS 1,0,0 9,0,0 ENDPICTS
SCRIPT
ON SELECT { dd GLOBAL crv GLOBAL co GLOBAL dt GLOBAL
myturn GLOBAL
{ dd "[456]" GREPSTR dt * crv =
ME co =
"@343,33 Ceci Vous Donne Un Score De " crv ITOA & LOCALMSG
} myturn ME GETSPOTSTATE NOT AND IF
}
ENDSCRIPT
ENDSPOT
SPOT
ID 21
DONTMOVEHERE
OUTLINE 311,41 366,41 366,56 311,56
LOC 343,49
PICTS 1,0,0 9,0,0 ENDPICTS
SCRIPT
ON SELECT { dd GLOBAL crv GLOBAL co GLOBAL dt GLOBAL
myturn GLOBAL
{ dd "[56]" GREPSTR dt * crv =
ME co =
"@343,51 Ceci Vous Donne Un Score De " crv ITOA & LOCALMSG
} myturn ME GETSPOTSTATE NOT AND IF
}
ENDSCRIPT
ENDSPOT
SPOT
ID 22
DONTMOVEHERE
OUTLINE 311,57 366,57 366,72 311,72
LOC 343,65
PICTS 1,0,0 9,0,0 ENDPICTS
SCRIPT
ON SELECT { dd GLOBAL crv GLOBAL co GLOBAL dt GLOBAL
myturn GLOBAL
{ dd "3.*3" GREPSTR 35 * crv =
ME co =
"@343,67 Ceci Vous Donne Un Score De " crv ITOA & LOCALMSG
} myturn ME GETSPOTSTATE NOT AND IF
}
ENDSCRIPT
ENDSPOT
SPOT
ID 23
DONTMOVEHERE
OUTLINE 311,73 366,73 366,88 311,88
LOC 343,81
PICTS 1,0,0 9,0,0 ENDPICTS
SCRIPT
ON SELECT { dd GLOBAL crv GLOBAL co GLOBAL dt GLOBAL
myturn GLOBAL
{ dd "4" SUBSTR dd "2" SUBSTR AND 35 * crv =
ME co =
"@343,82 Ceci Vous Donne Un Score De " crv ITOA & LOCALMSG
} myturn ME GETSPOTSTATE NOT AND IF
}
ENDSCRIPT
ENDSPOT
SPOT
ID 24
DONTMOVEHERE
OUTLINE 311,106 366,106 366,121 311,121
LOC 343,114
PICTS 1,0,0 9,0,0 ENDPICTS
SCRIPT
ON SELECT { dd GLOBAL crv GLOBAL co GLOBAL dt GLOBAL
myturn GLOBAL
{ dt crv = ME co =
"@343,117 Ceci Vous Donne Un Score De " crv ITOA & LOCALMSG
} myturn ME GETSPOTSTATE NOT AND IF
}
ENDSCRIPT
ENDSPOT
SPOT
ID 25
DONTMOVEHERE
OUTLINE 465,25 509,25 509,40 465,40
LOC 500,32
PICTS 1,0,0 9,0,0 ENDPICTS
SCRIPT
ON SELECT { dd GLOBAL crv GLOBAL co GLOBAL dt GLOBAL
myturn GLOBAL
{ dd " [123] [123] [123] [123] " GREPSTR 25 * crv =
ME co =
"@500,32 Ceci Vous Donne Un Score De " crv ITOA & LOCALMSG
} myturn ME GETSPOTSTATE NOT AND IF
}
ENDSCRIPT
ENDSPOT
SPOT
ID 26
DONTMOVEHERE
OUTLINE 465,41 509,41 509,57 465,57
LOC 500,49
PICTS 1,0,0 9,0,0 ENDPICTS
SCRIPT
ON SELECT { dd GLOBAL crv GLOBAL co GLOBAL dt GLOBAL
myturn GLOBAL
{ dd " [12] [12] [12] [12] [12] " GREPSTR 40 * crv =
ME co =
"@500,49 Ceci Vous Donne Un Score De " crv ITOA & LOCALMSG
} myturn ME GETSPOTSTATE NOT AND IF
}
ENDSCRIPT
ENDSPOT
SPOT
ID 27
DONTMOVEHERE
OUTLINE 465,58 509,58 509,74 465,74
LOC 500,66
PICTS 1,0,0 9,0,0 ENDPICTS
SCRIPT
ON SELECT { dd GLOBAL crv GLOBAL co GLOBAL dt GLOBAL
myturn GLOBAL
{ dd " 1 1 1 1 1 1 " GREPSTR 50 * crv =
ME co =
"@500,66 Ceci Vous Donne Un Score De " crv ITOA & LOCALMSG
} myturn ME GETSPOTSTATE NOT AND IF
}
ENDSCRIPT
ENDSPOT
SPOT
ID 28
DONTMOVEHERE
OUTLINE 311,89 366,89 366,105 311,105
LOC 343,97
PICTS 1,0,0 9,0,0 10,0,0 11,0,0 12,0,0 12,0,0 12,0,0 12,0,0 12,0,0 12,0,0 12,0,0 12,0,0 12,0,0 12,0,0 12,0,0 12,0,0 ENDPICTS
SCRIPT
ON SELECT { yhtz GLOBAL co GLOBAL dd GLOBAL myturn GLOBAL
crv GLOBAL mysc GLOBAL btt GLOBAL
{ dd "6" SUBSTR yts =
{
{ "Désoler, vous avez remplis votre ligne au Yahtzee-6 vous n'êtes pas éligible au bonus." LOCALMSG
} yts yhtz 0 < AND IF
{ ")applause " USERNAME " a reçus un bonus Yahtzee-6!" & & ROOMMSG
"@511,0 Le joker règne -- vous obtenez une marque sur une ligne régulière!!" LOCALMSG
200 mysc += ME GETSPOTSTATE 1 + ME SETSPOTSTATE
1 btt = yhtz ++
} yts yhtz 0 > AND btt NOT AND IF
}
{ ; yahtzee pour la première fois, -1 if yts is 0, 1 if yts is 1
yts 100 * crv = ME co =
"@343,101 Ceci vous donneras un pointage de " crv ITOA & LOCALMSG
{ "! ATTENTION: Si tu places zéro, tu n'es pas éligible au bonus pour le yahtzee-6 !" LOCALMSG
} crv NOT IF
} yhtz IFELSE
} myturn IF
}
ENDSCRIPT
ENDSPOT
SPOT
ID 29
DONTMOVEHERE
OUTLINE 454,77 483,77 483,101 454,101
LOC 491,91
PICTS 1,0,0 9,9,0 ENDPICTS
SCRIPT
ON SELECT { ut GLOBAL myturn GLOBAL
{
{ "@491,91 Vous avez besoin " 80 ut - ITOA & " plus de points pour obtenir la bonification supérieure de la table de bonus" & LOCALMSG }
{ "@491,91 Vous avez déjà la bonification supérieure de la table de bonus!" LOCALMSG
} ME GETSPOTSTATE NOT IFELSE
} myturn IF
ENDSCRIPT
ENDSPOT
SPOT
ID 12
DONTMOVEHERE
OUTLINE 232,140 266,140 266,184 232,184
LOC 245,162
PICTS 1,0,0 8,0,0 ENDPICTS
SCRIPT
ON SELECT { myturn GLOBAL
{ ME GETSPOTSTATE NOT ME SETSPOTSTATE
} myturn 32 GETSPOTSTATE AND IF
}
ENDSCRIPT
ENDSPOT
SPOT
ID 11
DONTMOVEHERE
OUTLINE 184,140 231,140 231,184 184,184
LOC 205,162
PICTS 1,0,0 8,0,0 ENDPICTS
SCRIPT
ON SELECT { myturn GLOBAL
{ ME GETSPOTSTATE NOT ME SETSPOTSTATE
} myturn 32 GETSPOTSTATE AND IF
}
ENDSCRIPT
ENDSPOT
SPOT
ID 10
DONTMOVEHERE
OUTLINE 141,140 184,140 184,184 141,184
LOC 164,162
PICTS 1,0,0 8,0,0 ENDPICTS
SCRIPT
ON SELECT { myturn GLOBAL
{ ME GETSPOTSTATE NOT ME SETSPOTSTATE
} myturn 32 GETSPOTSTATE AND IF
}
ENDSCRIPT
ENDSPOT
SPOT
ID 9
DONTMOVEHERE
OUTLINE 99,140 141,140 141,184 99,184
LOC 122,162
PICTS 1,0,0 8,0,0 ENDPICTS
SCRIPT
ON SELECT { myturn GLOBAL
{ ME GETSPOTSTATE NOT ME SETSPOTSTATE
} myturn 32 GETSPOTSTATE AND IF
}
ENDSCRIPT
ENDSPOT
SPOT
ID 8
DONTMOVEHERE
OUTLINE 58,140 99,140 99,184 58,184
LOC 81,162
PICTS 1,0,0 8,0,0 ENDPICTS
SCRIPT
ON SELECT { myturn GLOBAL
{ ME GETSPOTSTATE NOT ME SETSPOTSTATE
} myturn 32 GETSPOTSTATE AND IF
}
ENDSCRIPT
ENDSPOT
SPOT
ID 7
DONTMOVEHERE
OUTLINE 17,140 58,140 58,184 17,184
LOC 40,162
PICTS 1,0,0 8,0,0 ENDPICTS
SCRIPT
ON SELECT { myturn GLOBAL
{ ME GETSPOTSTATE NOT ME SETSPOTSTATE
} myturn 32 GETSPOTSTATE AND IF
}
ENDSCRIPT
ENDSPOT
SPOT
ID 31
NAME "Start Game"
DONTMOVEHERE
LOC 459,27
SCRIPT
ON ENTER { { " Une partie de YAHTZEE-6 est présentement en cours- clique jouer pour la joindre!" LOCALMSG } ME GETSPOTSTATE WHONAME "." GREPSTR IF
{ 0 ME SETSPOTSTATE } ME GETSPOTSTATE WHOME == IF
{ POSX 160 RANDOM 224 + SETPOS } POSY 225 < IF
ad GLOBAL "" ad =
"Script by Foxy, ©2003 Graphics by Tybalt & Speck ©2003" STATUSMSG
"Pour distribution gratuite seulement!" LOGMSG
{ DUP GLOBAL 0 SWAP =
} [ ref rollt crv mysc ut yhtz plyrs ckbxs myturn co lastroll] FOREACH
al27 GLOBAL
{ dt GLOBAL dd GLOBAL lastroll GLOBAL
{ { EXEC SETSPOTSTATE
} lastroll STRTOATOM EXEC FOREACH
} lastroll 0 != IF
0 dt = [ 0 0 0 0 0 0 ] dd =
"[ " lastroll =
{ dc = dc 6 + GETSPOTSTATE lck =
{ 6 RANDOM 1 + dv = dv dc SETSPOTSTATE }
{ dc GETSPOTSTATE dv = } lck NOT IFELSE
dv dt += dd dv 1 - GET 1 + dd dv 1 - PUT
lastroll "{" + dv ITOA + " " + dc ITOA + " }" + lastroll =
} [ 1 2 3 4 5 6 ] FOREACH
"[ " { ITOA + " " + } dd FOREACH
" ]" & dd =
lastroll "]" + lastroll =
{ "@105,268 )applause !YAHTZEE-6!!" ROOMMSG
} dd "6" SUBSTR IF
} al27 DEF
al26 GLOBAL
{ rollt GLOBAL dd GLOBAL dt GLOBAL
crv GLOBAL 0 crv = co GLOBAL 0 co =
{ ")dice2" SAY } rollt 6 == IF
{ 0 cr = rollt --
{ cr ++
{ 7 rollt cr + DUP 3 / 3 * - + cr SETSPOTSTATE
} cr 6 + GETSPOTSTATE NOT IF
} { cr 6 < } WHILE
al26 GLOBAL al26 30 ALARMEXEC
}
{ al27 GLOBAL al27 EXEC
} rollt IFELSE
} al26 DEF
al24 GLOBAL
{ plyrs GLOBAL hsc GLOBAL phsc GLOBAL ref GLOBAL
{ { "@0,100 ! Partie terminé!" ROOMMSG
{ "@100,100 ..et nôtre gagnant(e) est: " ROOMMSG
"@160,160 )applause !" phsc & "!!" & ROOMMSG
} hsc IF
0 ref = 1 sp =
{ 0 sp SETSPOTSTATE sp ++ } { sp 33 < } WHILE
{ ";Ÿ5" SAY } 60 ALARMEXEC
} plyrs "." GREPSTR NOT IF
} ref IF
} al24 DEF
al25 GLOBAL
{ plyrs GLOBAL al25 GLOBAL al24 GLOBAL
plyrs "^-([0-9]+)-(.*)$" GREPSTR POP
"$1" GREPSUB cp = "$2" GREPSUB oth =
{ oth GREPSUB plyrs = plyrs "^-([0-9]+)-(.*)$" GREPSTR POP
"$1" GREPSUB cp = "$2" GREPSUB oth =
} { cp ATOI WHONAME "." GREPSTR NOT plyrs "" == NOT AND } WHILE
{ "@" cp ATOI WHOPOS ITOA SWAP ITOA " " & SWAP & & cp ATOI WHONAME " C'est à mon tour !" & & ROOMMSG
";Ÿ3" cp & cp ATOI PRIVATEMSG
oth "-" & cp & "-" & plyrs =
}
{ al24 30 ALARMEXEC
} plyrs "" == NOT IFELSE
} al25 DEF
}
ON SELECT { ref GLOBAL plyrs GLOBAL ad GLOBAL hsc GLOBAL phsc GLOBAL
{ { " La partie est présentement commencé. Clique jouer pour prendre place. " LOCALMSG }
{ " Mettre a zero la partie (reset), clique sur début pour une nouvelle partie. " LOCALMSG
0 ME SETSPOTSTATE ";Ÿ5" SAY
{ cr ++ 0 cr SETSPOTSTATE } { cr 29 < } WHILE
} ME GETSPOTSTATE WHONAME "." GREPSTR IFELSE
}
{ WHOME ME SETSPOTSTATE 1 ref = "" plyrs = "-" ad = 0 hsc = "" phsc =
USERNAME " a commencé un jeu de Yahtzee-6! Pour joindre le jeu cliquez sur jouer " & ROOMMSG
"@511,0" USERNAME & ",Cliquez le bouton lancer pour commencer le jeu après que tous les joueurs se soit joint. " & LOCALMSG
} ME GETSPOTSTATE IFELSE
}
ON INCHAT { ref GLOBAL plyrs GLOBAL phsc GLOBAL hsc GLOBAL
{
{ DUP GLOBAL 0 SWAP =
} [ ref rollt crv mysc ut yhtz plyrs ckbxs myturn co phsc hsc btt lastroll] FOREACH
"" plyrs =
} CHATSTR ";Ÿ5" == IF
{ 0 ref = "" plyrs = "" phsc = 0 hsc =
} ref WHOME ME GETSPOTSTATE <> AND IF
;26 inchat
mysc GLOBAL ckbxs GLOBAL ut GLOBAL yhtz GLOBAL
rollt GLOBAL myturn GLOBAL co GLOBAL dd GLOBAL dt GLOBAL
{ { 0 SWAP SETSPOTSTATE } [ 7 8 9 10 11 12] FOREACH
1 myturn = 13 sp = ckbxs tckbxs =
{ tckbxs DUP 2 / 2 * - sp SETSPOTSTATE
2 tckbxs /= sp ++
} { sp 28 < } WHILE
{ 1 28 SETSPOTSTATE
{ yhtz 28 SETSPOTSTATE } yhtz 1 > IF
}
{ 0 28 SETSPOTSTATE } yhtz IFELSE
0 32 SETSPOTSTATE 0 crv = 0 co =
"[0 0 0 0 0 0]" dd = 0 dt =
ut 80 >= 29 SETSPOTSTATE
{ 0 SWAP SETSPOTSTATE } [ 1 2 3 4 5 6 ] FOREACH
} ";Ÿ3" WHOME ITOA & CHATSTR == IF
;25 inchat
ref GLOBAL plyrs GLOBAL ad GLOBAL
mysc GLOBAL ckbxs GLOBAL ut GLOBAL yhtz GLOBAL
plyrs GLOBAL hsc GLOBAL phsc GLOBAL al25 GLOBAL
ad "." GREPSTR stt =
{ "-" WHOCHAT ITOA & "-" & ad =
{ " Tu est déja en jeu," WHOCHAT WHONAME &
WHOCHAT PRIVATEMSG
}
{ WHOCHAT WHONAME " à joint le jeu!" & ROOMMSG
";Ÿ2" WHOCHAT ITOA & WHOCHAT PRIVATEMSG
ad plyrs & plyrs =
} plyrs ad SUBSTR IFELSE
{ "" ad = } stt NOT IF
} CHATSTR ";Ÿ1" == ref AND IF
{ ;initialize variables to play
0 mysc = 0 ckbxs = 0 ut = 0 yhtz =
} CHATSTR ";Ÿ2" WHOME ITOA & == IF
{ al25 90 ALARMEXEC
} ";Ÿ3" CHATSTR == ref AND IF
{ "-$1-" GREPSUB pq =
"$2" GREPSUB ATOI ps =
")applause !" "$1" GREPSUB ATOI WHONAME " a terminé avec des points finals de " & &
"$2!" GREPSUB & ROOMMSG
{ "@150,0 ! Meilleur pointage dans cette partie BRAVO !" ROOMMSG
"$1" GREPSUB ATOI WHONAME phsc = ps hsc =
} ps hsc > IF
plyrs "^(.*)" pq & "(.*)$" & GREPSTR POP
"$1$2" GREPSUB plyrs =
al24 GLOBAL al24 60 ALARMEXEC al25 120 ALARMEXEC
} CHATSTR "^;Ÿ4([0-9]+)-([0-9]+)$" GREPSTR ref AND IF
{ { "$1$2" GREPSUB plyrs =
WHOCHAT WHONAME " as quitté la partie !" & ROOMMSG
{ al25 EXEC } "$2" GREPSUB "" == IF
} plyrs "^(.*)-" WHOCHAT ITOA "-(.*)$" & & GREPSTR IF
} CHATSTR ";Ÿ6" == ref AND IF
}
ON OUTCHAT { { "" CHATSTR = } CHATSTR "^;Ÿ" GREPSTR IF
ref GLOBAL plyrs GLOBAL al25 GLOBAL
{ "" CHATSTR = plyrs tp = "[ " plar = "$1" GREPSUB ATOI drp =
{ plar " $1 " GREPSUB & plar = "$2" GREPSUB tp =
} { tp "^-([0-9]+)-(.*)$" GREPSTR } WHILE
plar "]" & STRTOATOM EXEC plar =
{ drp -- "" plyrs = 0 cnt =
{ ts =
{ plyrs "-" & ts ITOA & "-" & plyrs = }
{ "Dropping " ts WHONAME & " du jeu & LOGMSG
} cnt drp != IFELSE
cnt ++
} plar FOREACH
} drp 0 > plar LENGTH drp >= AND IF
{ al25 25 ALARMEXEC } plar LENGTH drp 1 + == IF
} ref CHATSTR "player drop *([0-9]+)$" GREPSTR AND IF
{ "" CHATSTR = plyrs tp = 0 ps =
"Current players:" LOGMSG
{ ps ++ ps ITOA ". " & "$1" GREPSUB ATOI WHONAME & LOGMSG
"$2" GREPSUB tp =
} { tp "^-([0-9]+)-(.*)$" GREPSTR } WHILE
} ref CHATSTR "liste de joueurs" == AND IF
}
ON LEAVE { ";Ÿ6" SAY }
ENDSCRIPT
ENDSPOT
SPOT
ID 32
NAME "Start - Play - Roll - Quit - Instructions"
DONTMOVEHERE
OUTLINE 303,140 504,140 504,184 303,184
LOC 392,156
PICTS 13,79,-39 13,98,-39 13,117,-39 13,136,-39 1,0,0 ENDPICTS
SCRIPT
ON SELECT { MOUSEPOS POP ys =
0 ss =
{ ys < ss += } [ 341 383 423 464 ] FOREACH
[
;"Start"
{31 SELECT}
;"Play"
{ myturn GLOBAL btt GLOBAL lastroll GLOBAL
{ co GLOBAL crv GLOBAL mysc GLOBAL ut GLOBAL ckbxs GLOBAL
dd GLOBAL yhtz GLOBAL
{ crv mysc +=
0 btt =
{ { "@491,91
! BONIFICATION DE LA TABLE DE !BONUS !" ROOMMSG 50 mysc +=
} ut 80 < crv ut + 80 >= AND IF
crv ut +=
} co 19 < IF
"J'ai un pointage de " mysc ITOA & SAY
{ 1 co SETSPOTSTATE } co 28 < IF
{ 1 co SETSPOTSTATE dd "6" SUBSTR 2 * 1 - yhtz =
} co 28 == yhtz NOT AND IF
12 cs = 0 ckbxs = 1 vl =
{ cs ++ cs GETSPOTSTATE ckd = { 1 ckd = } cs co == IF
{ vl ckbxs += } ckd IF 2 vl *=
} { cs 27 < } WHILE
0 myturn =
{ ";Ÿ3" SAY }
{ ; { 50 mysc += } ut 80 > IF
";Ÿ4" WHOME ITOA & "-" & mysc ITOA & SAY
{ DUP GLOBAL 0 SWAP =
} [ rollt crv mysc ut yhtz ckbxs myturn co btt ] FOREACH
} ckbxs 32767 < yhtz NOT OR IFELSE
} co IF
}
{ ";Ÿ1" SAY "dice2" SOUND } myturn IFELSE
}
;"Roll"
{ ref GLOBAL ad GLOBAL rollt GLOBAL crv GLOBAL myturn GLOBAL al25 GLOBAL
{ "" ad = al25 EXEC }
{ { { ME GETSPOTSTATE 1 + ME SETSPOTSTATE
6 rollt = 0 crv =
al26 GLOBAL al26 EXEC
}ME GETSPOTSTATE 4 < IF
} myturn IF
} ref ad ".." GREPSTR AND IFELSE
}
;"Instructions"
{
"Les Instruction sont dans le log" STATUSMSG
{ LOGMSG } [
"" "***YAHTZEE 6 RULES***" ""
"Six dice, four rolls!"
"Upper Table, Triples, Quads, Short & Full Straights, & Chance:"
" --all qualify the same as regular Yahtzee"
"Yahtzee is now 6 of a kind"
"Pents 5 pareil"
"Six Straight is 1, 2, 3, 4, 5, and 6, in any order"
"Main Plein 4 pareil et 2 pareil"
"Main Double 3 pareil et 3 pareil"
"Upper Table Bonus is fifty points when you score eighty in the upper table"
" Examinez le conseil pour assurer d'autres changements de points !"
"" "***General Play***" ""
"Pour Débuter une Partie Une Personne Clique Début." LOGMSG
"Toute les personnes Souhaitant jouer y compris la personne qui a débuté la partie
doivent cliquer Jouer." LOGMSG
"Une Fois Toute Les Personnes Prêtes Le maître de la partie clique Lancer." LOGMSG
"Tout Le Monde Peut Joindre La partie n'importe quand." LOGMSG
"Vous Pouvez partir de la partie en appuyant Quitter." LOGMSG
"Les Personne Qui Quitterons La salle Quitterons Aussi La Partie!" LOGMSG
"Ci Vous Ne Voulez Pas qu'une personne joue a votre partie dite \x22remove (nom)\x22
Et Il Quittera Automatiquement "LOGMSG
"Ci Le maître Quitte La salle La Partie Ce Termine!" LOGMSG
"Clique Sur Début Pour Recommencer." LOGMSG
"Pour Lancer Les Dés Cliquer Lancer "LOGMSG
"Pour Choisir Les Dés Cliquer Sur Les Dés Que Vous Voulez." LOGMSG
"Pour Placer Votre Score Cliquer Sur La Partie Verte Du Tableau Et Ensuite Cliquer
Jouer Pour Accepter." LOGMSG
"Bonne chance." LOGMSG
"NOTE: Il Est Recommander D'avoir La Version 3.5 Bonne Partie =)!" LOGMSG
] FOREACH
}
;"Quit"
{ ref GLOBAL ";Ÿ6" SAY
{ { DUP GLOBAL 0 SWAP =
} [ rollt crv mysc ut yhtz ckbxs myturn co btt lastroll] FOREACH
}
{";Ÿ5" WHOME PRIVATEMSG } ref IFELSE
}
] ss GET EXEC
}
ENDSCRIPT
ENDSPOT
ENDROOM