ROOM
	ID 305
	NOCYBORGS
	NAME "Simon Dit"
	PICT "fh-ss1.gif"
	PICTURE ID 1 NAME "otp9.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 2 NAME "fh-ss-bl.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 4 NAME "fh-ss-yl.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 5 NAME "fh-ss-gr.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 6 NAME "fh-ss-rd.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 8 NAME "fh-ss-son.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 9 NAME "fh-ss-sof.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 10 NAME "arrowll.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 11 NAME "arrowrr.gif" TRANSCOLOR 0 ENDPICTURE
	SPOT
		ID 1
		DONTMOVEHERE
		OUTLINE 187,115  246,115  246,175  187,175
		LOC 216,146
		PICTS 1,0,0 2,0,0 ENDPICTS
		SCRIPT
ON SELECT { ssc GLOBAL ME ssc EXEC }
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 2
		DONTMOVEHERE
		OUTLINE 268,119  324,119  325,177  268,178
		LOC 296,148
		PICTS 1,0,0 4,0,0 ENDPICTS
		SCRIPT
ON SELECT { ssc GLOBAL ME ssc EXEC }
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 3
		DONTMOVEHERE
		OUTLINE 184,196  246,196  244,255  185,256
		LOC 214,224
		PICTS 1,0,0 5,0,0 ENDPICTS
		SCRIPT
ON SELECT { ssc GLOBAL ME ssc EXEC }
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 4
		DONTMOVEHERE
		OUTLINE 261,198  321,198  321,256  261,256
		LOC 293,227
		PICTS 1,0,0 6,0,0 ENDPICTS
		SCRIPT
ON SELECT { ssc GLOBAL ME ssc EXEC }
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 5
		OUTLINE 79,56  109,58  111,81  80,75
		LOC 87,71
		SCRIPT
;~MediaList~;e.wav,g.wav,c.wav,a.wav		
ON ENTER { ssc GLOBAL ms GLOBAL btw GLOBAL
"Script and Graphics by Foxy, ©1999" STATUSMSG
"" ms = 0 btw =
{ se = { DUP se == SWAP SETSPOTSTATELOCAL }
[ 1 2 3 4 ] FOREACH
{ [ "E" "G" "C" "A" ] se 1 - GET SOUND
} 7 GETSPOTSTATE NOT IF
{ { 0 ME SETSPOTSTATELOCAL } 35 ALARMEXEC
} btw 2 == btw 0 == OR IF
btw GLOBAL gs GLOBAL wg GLOBAL ps GLOBAL ms GLOBAL
curs GLOBAL
{ gs "^(.)(.*)" GREPSTR POP "$1" GREPSUB ATOI sb =
"$2" GREPSUB gs =
{ "@256,186 )no !TROMPÉ!" LOCALMSG wg ++ "20" gs =
{ 0 SWAP SETSPOTSTATELOCAL } [ 1 2 3 4 ] FOREACH
{ "@256,192 Jeu terminé" LOCALMSG 1 10 SETALARM }
{ 1 btw = ms ps = 90 5 SETALARM
} wg 3 == IFELSE
} sb se == NOT IF
{  "@256,186 )yes Correcte!" LOCALMSG    curs ++
ms "^(.*)(.)$" GREPSTR POP
"$1" GREPSUB  4 RANDOM 1 + ITOA + "0" + ms =
1 btw = ms ps =   90 5 SETALARM
} "0" gs == IF
} btw 2 == IF
} ssc DEF
}
ON ALARM { ps GLOBAL ms GLOBAL btw GLOBAL gs GLOBAL
ssc GLOBAL
{ "$1" GREPSUB ATOI np = "$2" GREPSUB ps =
{ np ssc EXEC 45 ME SETALARM -1 btw = }
{ 2 btw = ms gs = { 0 SWAP SETSPOTSTATELOCAL } [ 1 2 3 4 ] FOREACH
} np IFELSE
}
{ { 1 btw = 30 ME SETALARM
{ 0 SWAP SETSPOTSTATELOCAL } [ 1 2 3 4 ] FOREACH
} -1 btw == IF
} btw 1 == ps "^(.)(.*)$" GREPSTR AND IFELSE
}
; "a.wav-*"
; "g.wav-*"
; "c.wav-*"
; "e.wav-*"
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 6
		NAME "Play"
		DONTMOVEHERE
		OUTLINE 8,38  59,38  59,61  8,61
		LOC 36,48
		SCRIPT
ON SELECT { ms GLOBAL btw GLOBAL ps GLOBAL wg GLOBAL
curs GLOBAL
{ "0" ms =  1 btw = 0 wg = 0 curs =
4 RANDOM 1 + ITOA ms + ms =
ms ps =  1 5 SETALARM
} ms "." GREPSTR NOT IF
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 7
		DONTMOVEHERE
		OUTLINE 6,5  107,5  107,30  6,30
		LOC 57,17
		PICTS 8,0,0 9,0,0 ENDPICTS
		SCRIPT
ON SELECT { ME GETSPOTSTATE NOT ME SETSPOTSTATELOCAL }
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 8
		DONTMOVEHERE
		OUTLINE 8,70  60,70  60,93  8,93
		LOC 35,82
		SCRIPT
ON SELECT { 1 10 SETALARM }
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 9
		DONTMOVEHERE
		OUTLINE 365,6  504,6  504,26  365,26
		LOC 435,17
		SCRIPT
ON SELECT { curs GLOBAL

"@511,0 Les points actuels sont: " curs ITOA + LOCALMSG

}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 10
		DONTMOVEHERE
		OUTLINE 390,32  501,32  501,57  390,57
		LOC 447,44
		SCRIPT
ON SELECT {

"@511,0 Les hauts points actuels sont" 5 GETSPOTSTATE ITOA + LOCALMSG

}
ON ALARM { ms GLOBAL btw GLOBAL curs GLOBAL "" ms = 0 btw =
5 GETSPOTSTATE chs =

{ ")applause ! Mesdames et messieurs, nous avons de NOUVEAUX POINTAGE de "

curs ITOA + " by " USERNAME UPPERCASE + "!" + + ROOMMSG
curs chs = curs 5 SETSPOTSTATE
} curs chs > IF

"@256,100 Vos points final: " curs ITOA + LOCALMSG

"@256,200 Haut pointage: " chs ITOA + LOCALMSG
0 curs =
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 11
		DONTMOVEHERE
		OUTLINE 450,62  501,62  501,88  450,88
		LOC 474,77
		SCRIPT
ON SELECT {

" Les instructions sont dans votre Log " LOCALMSG

" Pour commencer le jeu, cliquez simplement le bouton de début. Une lumière clignote pour commencer ." LOGMSG

" Cliquez sur cette lumière, et vous obtenez alors deux lumières." LOGMSG

" Répétez l'ordre de nouveau à chaque fois." LOGMSG

" Si vous répétez mal l'ordre, il le répétera pour vous " LOGMSG

" Après trois conjectures fausses, le jeu ce termine." LOGMSG

" Cliquer sur quitté pour laisser la partie." LOGMSG

"Cliquer sur le son on/off pour entendre ou fermer les sons." LOGMSG

" Les points vous font savoir le plus long ordre répété correctement." LOGMSG

}
		ENDSCRIPT
		ENDSPOT
	DOOR
		ID 12
		DONTMOVEHERE
		DEST 347
		OUTLINE 4,354  62,354  62,380  4,380
		LOC 33,366
		PICTS 10,0,0 ENDPICTS
		ENDDOOR
	DOOR
		ID 13
		DONTMOVEHERE
		DEST 244
		OUTLINE 448,354  508,354  508,379  448,379
		LOC 480,368
		PICTS 11,0,0 ENDPICTS
		SCRIPT
ON INCHAT { nDoIt GLOBAL nDoIt EXEC }
ON ENTER { { CLEARLOOSEPROPS PAINTCLEAR } NBRROOMUSERS 2 < IF }
		ENDSCRIPT
		ENDDOOR
	ENDROOM